home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD018b.dsk / LOW RES PAINTER.bas < prev    next >
BASIC Source File  |  2003-06-12  |  4KB  |  93 lines
  1. 5  ONERR  GOTO 800
  2. 6  PRINT  CHR$(4)"BLOAD LOW RES PAINTER INST,A2048"
  3. 7 X =  PEEK( -16299): GET ZZ$: PRINT ZZ$: TEXT 
  4. 10  HOME 
  5. 15  GOTO 700
  6. 20  GR 
  7. 30  GOSUB 510
  8. 32  PRINT : INPUT "SELECT BACKGROUND COLOR --> ";BK: COLOR= BK
  9. 35  INPUT "SELECT BRUSH COLOR --> ";HUE
  10. 38  IF Q1$ = "Y"  OR Q1$ = "YES"  THEN  GOTO 45
  11. 40  FOR COL = 0 TO 39: VLIN 0,39 AT COL: NEXT COL
  12. 45  HOME : VTAB 21
  13. 50  COLOR= HUE
  14. 60 COL = 20:ROW = 20
  15. 70 X =  PEEK( -16368)
  16. 80  PLOT COL,ROW
  17. 90  HOME : VTAB 21: HTAB 12: PRINT "X","Y": HTAB 12: PRINT COL,ROW
  18. 100 X =  PEEK( -16384)
  19. 110  IF X <128  THEN  GOTO 100
  20. 111  IF X = 191  AND I = 0  THEN I = 1:X =  PEEK( -16303):X =  PEEK( -16299): POKE  -16368,0: GOTO 100
  21. 112  IF X = 141  AND I = 1  THEN I = 0:X =  PEEK( -16300):X =  PEEK( -16304): POKE  -16368,0: GOTO 100
  22. 115  IF X >136  AND X <142  THEN  GOTO 165
  23. 116  IF X = 155  THEN X =  PEEK( -16368): GOSUB 400
  24. 117  IF X = 209  THEN X =  PEEK( -16368): GOTO 600
  25. 118  IF X = 195  THEN X =  PEEK( -16368): GOTO 200
  26. 119  IF X = 216  THEN X =  PEEK( -16368): HOME : VTAB 21: INPUT "NEW BRUSH COLOR -->";HUE: COLOR= HUE: GOTO 80
  27. 120  IF X = 201  THEN ROW = ROW -1
  28. 121  IF X = 202  THEN COL = COL -1
  29. 123  IF X = 203  THEN COL = COL +1
  30. 124  IF X = 205  THEN ROW = ROW +1
  31. 125  IF ROW >39  THEN ROW = ROW -1: PRINT  CHR$(7)
  32. 150  IF  SCRN( COL,ROW) < >HUE  THEN  GOTO 70
  33. 160  COLOR= BK: PLOT COL,ROW: COLOR= HUE: GOTO 70
  34. 165  COLOR= BK: PLOT COL,ROW: COLOR= HUE
  35. 170 X = X +64: GOTO 120
  36. 200  GOSUB 500
  37. 202  GR : GOSUB 510
  38. 203  PRINT : INPUT "SELECT NEW BRUSH COLOR --> ";HUE
  39. 205  PRINT  CHR$(4);"BLOAD SCREEN"
  40. 210  COLOR= HUE: GOTO 80
  41. 400  REM    MOVE WITHOUT DRAWING
  42. 401  IF PL$ < >"OFF"  THEN  COLOR= BK: PLOT COL,ROW
  43. 402  VTAB 24: PRINT "PLOT IS OFF";
  44. 405 PL$ = "OFF"
  45. 410 X =  PEEK( -16384)
  46. 411  IF X <128  THEN  GOTO 410
  47. 415  IF X = 155  THEN X =  PEEK( -16368): HOME : VTAB 21: HTAB 12: PRINT "X","Y": HTAB 12: PRINT COL,ROW: GOTO 499
  48. 440  IF X = 201  THEN ROW = ROW -1
  49. 441  IF X = 202  THEN COL = COL -1
  50. 442  IF X = 203  THEN COL = COL +1
  51. 443  IF X = 205  THEN ROW = ROW +1
  52. 450  HOME : VTAB 21: HTAB 12: PRINT "X","Y": HTAB 12: PRINT COL,ROW: PRINT "PLOT IS OFF";
  53. 460 SC =  SCRN( COL,ROW): COLOR= 0
  54. 465  FOR CT = 1 TO 5: PLOT COL,ROW: NEXT 
  55. 467  COLOR= SC: PLOT COL,ROW: GOTO 480
  56. 480 X =  PEEK( -16368): GOTO 410
  57. 499 PL$ = "ON": COLOR= HUE: PLOT COL,ROW: RETURN 
  58. 500  HOME : VTAB 21: PRINT "ONE MOMENT ... I'M MEMORIZING THE SCREEN"
  59. 501  PRINT  CHR$(4);"BSAVE SCREEN,A1024,L1024"
  60. 505  RETURN 
  61. 510  COLOR= 5: VLIN 0,39 AT 3: VLIN 0,39 AT 36
  62. 520  FOR QQ = 0 TO 15: COLOR= QQ: VLIN 0,39 AT 4 +QQ *2: VLIN 0,39 AT 5 +QQ *2
  63. 521  NEXT QQ
  64. 530  HOME : VTAB 21: FOR WW = 0 TO 14  STEP 2: HTAB (6 +WW *4/2 - INT(WW/10)): PRINT WW;: NEXT WW
  65. 535  PRINT 
  66. 540  FOR WW = 1 TO 15  STEP 2: HTAB (6 +WW *4/2 - INT(WW/10)): PRINT WW;: NEXT WW
  67. 550  RETURN 
  68. 600  HOME : VTAB 22: PRINT "(RETURN ONLY WILL NOT SAVE PICTURE)": VTAB 21: INPUT "PICTURE NAME --> ";P$: IF P$ = ""  THEN  GOTO 699
  69. 610  HOME 
  70. 620  PRINT  CHR$(4);"BSAVE";P$;",A1024,L1024"
  71. 699  TEXT : HOME : END 
  72. 700  VTAB 5: PRINT "DO YOU WISH TO WORK ON A SAVED PICTURE": VTAB 7: HTAB 18: INPUT "";Q1$
  73. 710  IF Q1$ = "Y"  OR Q1$ = "YES"  THEN  GOTO 750
  74. 720  GOTO 20
  75. 750  VTAB 12: INPUT "NAME OF PICTURE ? ";PI$
  76. 760  GR : PRINT  CHR$(4);"BLOAD";PI$
  77. 770  GOTO 32
  78. 800  REM    ERROR ROUTINES
  79. 801  REM    OUT OF BOUNDS ERROR
  80. 810  IF  PEEK(222) < >53  THEN  GOTO 850
  81. 812  PRINT  CHR$(7)
  82. 813  IF COL <0  THEN COL = COL +1
  83. 814  IF COL >39  THEN COL = COL -1
  84. 815  IF ROW <0  THEN ROW = ROW +1
  85. 816  IF ROW >48  THEN ROW = ROW -1
  86. 820 X =  PEEK( -16368)
  87. 840  IF PL$ = "OFF"  THEN  GOSUB 400
  88. 845  GOTO 70
  89. 850  REM    OTHER ERRORS
  90. 855  IF  PEEK(222) = 255  THEN  GOTO 890
  91. 860  HOME : VTAB 23: PRINT  CHR$(7);"ERROR # "; PEEK(222);" AT LINE "; PEEK(218) + PEEK(219) *256;
  92. 890  REM    CTRL-C 
  93. 899  STOP